.def	temp1=R16
.def	temp2=R17
.def	u_data=R18

.equ	USART0_port_pin = pine
.equ	USART0_RXD_pin = PE0

;*****	Начальный загрузчик для контроллера mega128
;	( с USART и 128к памяти программ )

.cseg
.equ	BOOTLOADER = SMALLBOOTSTART

.org	BOOTLOADER
	nop
	in 	temp1,mcucsr		; Источник сброса?
	sbrs	temp1,PORF		; Bootloader только по включению питания
	rjmp	boot_to_start_vector	; Иначе - запуск программы

	andi	temp1,~(1<<PORF)
	out	mcucsr,temp1		; Сброс PORF

boot_soft:	
	cli
	ser	temp1
	sts	osccal,temp1	; максимальная частота RC-генератора

	out	spl,temp1
	ldi	temp1,1
	out	sph,temp1	; Инициализация стека ( на 0x01FF )
	cbi	USART0_port_pin+1,USART0_RXD_pin	; PE0 - вход

	ldi	temp1,(1<<WDTOE)+(1<<WDE)+(1<<WDP0)+(1<<WDP1)+(1<<WDP2)
	out	wdtcr,temp1
	ldi	temp1,(1<<WDE)+(1<<WDP0)+(1<<WDP1)+(1<<WDP2)
	wdr			; Ожидание загрузки по сторожевому
	out	wdtcr,temp1	; таймеру
	
	ldi	temp2,0x10	; Подбор тактовой частоты и установление
	clr	XL		; связи по RS232
	clr	XH		
boot_new_cycle:
	clr	temp1	
	out	tcnt1h,temp1
	out	tcnt1l,temp1	; Обнуление таймера

boot_wait_pause:
	sbis	USART0_port_pin,USART0_RXD_pin
	rjmp	boot_wait_pause

	ldi	temp1,2		
boot_wait_start:		; Стартовый бит
	sbic	USART0_port_pin,USART0_RXD_pin
	rjmp	boot_wait_start
	out	tccr1b,temp1	; Запуск таймера

boot_wait_8bits:
	sbis	USART0_port_pin,USART0_RXD_pin
	rjmp	boot_wait_8bits
		
	clr	temp1
	out	tccr1b,temp1	; Остановить таймер и считать данные
	in	temp1,tcnt1l
	add	XL,temp1
	in	temp1,tcnt1h
	adc	XH,temp1
	
	dec	temp2		; Набор статистики, 16 повторов.
	brne	boot_new_cycle	; XH:XL = 256 * (Baud+1)

	subi	XL,0x80
	sbci	XH,0		; XH = round(XH:XL) - 1
	
	ldi	temp1,(1<<WDTOE)+(1<<WDE)+(1<<WDP0)+(1<<WDP1)+(1<<WDP2)
	out	wdtcr,temp1
	ldi	temp1,(1<<WDTOE)
	out	wdtcr,temp1	; Остановка сторожевого таймера
	
boot_wait_pause1:
	sbis	USART0_port_pin,USART0_RXD_pin
	rjmp	boot_wait_pause1

	sts	ubrr0h,temp2	; Настройка УСАПП ©0 в асинхронном
	out	ubrr0l,XH	; режиме: 8 бит данных, 2 стоп-бита
	sts	ucsr0a,temp2
	ldi	temp1,(1<<USBS)+(1<<UCSZ1)+(1<<UCSZ0)
	sts	ucsr0c,temp1
	ldi	temp1,(1<<TXEN)+(1<<RXEN)
	out	ucsr0b,temp1
boot_clear_RXC:
	in	u_data,udr0	; Сброс RXC
;	sbic	ucsr0a,RXC
;	rjmp	boot_clear_RXC
	
	mov	u_data,XH
	rcall	boot_transmit
	mov	u_data,XL
	rcall	boot_transmit	; Достаточна-ли точность?
	
boot_main_proc:
	ldi	u_data,0xD		; Передача подтверждения
	brtc	boot_no_overflow	; Переполнение регистра приёмника?
	clt
	ldi	u_data,0x1B	; Передать "сбой"
boot_no_overflow:
	rcall	boot_transmit
	rcall	boot_receive	; Ожидание команды
	
	cpi	u_data,0	; Холостая команда
	breq	boot_main_proc
	
	sbrs 	u_data,5	; Загрузка регистровой пары R0:R1 или ZL:ZH
	rjmp	boot_buf_load	; хх1а аааа: 1 - признак, а - адрес рег. пары
	
	andi	u_data,0x1F
	mov	XL,u_data
	ldi	XH,0
	rcall	boot_receive
	st	X+,u_data
	rcall	boot_receive
	st	X,u_data

	rjmp	boot_main_proc	; Послать подтверждение и повторить

;*****	Подпрограммы	*****
boot_do_spm:			; Загрузка SPMCR и вызов SPM
	sbic 	eecr, EEWE	; Запись EEPROM не стоит на дороге?
	rjmp 	boot_do_spm

	sts	spmcsr,temp1
	spm
.dw 	0xFFFF 			; ensure proper pipelining
	nop

boot_wait_spm:
	lds 	temp1,spmcsr
	sbrc 	temp1,SPMEN	; Команда выполнена?
	rjmp	boot_wait_spm
	ret

boot_receive:			; Приём байта через УСАПП
	sbis	ucsr0a,RXC
	rjmp	boot_receive
	sbic	ucsr0a,DOR
	set			; Переполнение регистра приёмника
	in	u_data,udr0
	ret			; end receive
	
boot_transmit:			; Передача байта через УCАПП
	sbis	ucsr0a,UDRE
	rjmp	boot_transmit
	out	udr0,u_data
	ret			; end transmit
;*****	Подпрограммы	*****

boot_buf_load:			; 1 - Загрузка буфера страницы...
	andi	u_data,0xDF
	cpi 	u_data,0x1
	brne	boot_mem_read

	rcall	boot_receive
	mov	temp2,u_data	; ...в количестве temp2 слов
boot_do_buf_load:
	rcall	boot_receive
	mov	r0,u_data
	rcall	boot_receive
	mov	r1,u_data	; Загрузка слова
	ldi	temp1,(1<<SPMEN)
	rcall	boot_do_spm	; Запись буфера
	adiw	ZH:ZL,2
	dec	temp2
	brne	boot_do_buf_load

	rjmp	boot_main_proc	; Послать подтверждение и повторить

boot_mem_read:			; 2 - Чтение памяти команд от ZH:ZL до
	cpi 	u_data,0x2	; ZH:ZL+count байт ( LPM/ELPM ).
	brne	boot_ctrl_load

	rcall	boot_receive
	mov	temp2,u_data	; Загрузка count
boot_do_mem_read:
;	!!!!!
	elpm	u_data,Z+		; Только для mega128 ( 128k FLASH ) 
;	!!!!!
	rcall	boot_transmit
	dec	temp2	
	brne	boot_do_mem_read

	rjmp	boot_main_proc	; Послать подтверждение и повторить

boot_ctrl_load:			; 3 - Загрузка SPMCR и вызов SPM
	cpi 	u_data,0x3	
	brne	boot_bits_read
	
	rcall	boot_receive
	mov	temp1,u_data
	rcall	boot_do_spm

	rjmp	boot_main_proc	; Послать подтверждение и повторить

boot_bits_read:			; 4 - Загрузка SPMCR и вызов LPM
	cpi 	u_data,0x4	
	brne	boot_rampz_load
	
	rcall	boot_receive
	sts	spmcsr,u_data	; Загрузка SPMCR
	lpm	u_data,Z+	; Чтение битов конфигурации и защиты
	rcall	boot_transmit
	
	rjmp	boot_main_proc	; Послать подтверждение и повторить

boot_rampz_load:		; 5 - Загрузка RAMPZ
	cpi 	u_data,0x5	
	brne	boot_exit
	
	rcall	boot_receive
	out	rampz,u_data	

	rjmp	boot_main_proc	; Послать подтверждение и повторить

boot_exit:
	cpi 	u_data,0x80	; 128 - Выход
	breq	boot_wait_enable_app
	rjmp	boot_main_proc	; Послать подтверждение и повторить
	
boot_wait_enable_app:		; Ожидание освобождения "application section"
	lds	temp1,spmcsr
	andi	temp1,(1<<RWWSB)
	brne	boot_wait_enable_app
	rjmp	boot_to_start_vector	; Передача управления на адрес 0x0000

.org	FLASHEND

.equ	RCbyte	= 0x93			; Калибровочный байт RC-генератора
.equ	Version	= 0x12			; Версия начального загрузчика
.dw	RCbyte*256+Version

.org	FLASHEND+1
boot_to_start_vector:		; Старт основной программы
				; ( адрес FLASHEND+1 = 0x00000 )
.exit